Das Lorenz System

dx/dt = σ (x-y)
dy/dt = rx -y -xz
dz/dt = xy - bz

Die Parameter σ und b werden fest gewählt / Der Interessante Bereich liegt oberhalb von r = 25

σ:=10

b:=N[8/3]

ODE[σ_,b_,r_]:={x'[t]==σ( y[t]- x[t]),y'[t]==r x[t]-y[t]-x[t]z[t],z'[t]==x[t]y[t]- b z[t]}

Lösung des Systems wird durch NDSolve gegeben

ODEsol[σ_,b_,r_,x0_,y0_,z0_,T_]:=NDSolve[{ODE[σ,b,r],x[0]==x0,y[0]==y0,z[0]==z0},{x[t],y[t],z[t]},{t,0,T}]

Die Trajektorie wird als parametrischer Plot der Lösung definiert

ODETrajectory[σ_,b_,r_,x0_,y0_,z0_,T_]:=ParametricPlot3D[Evaluate[{x[t],y[t],z[t]}/.ODEsol[σ,b,r,x0,y0,z0,T]],{t,0,T},PlotRange->{{-30,30},{-40,40},{0,80}},Boxed->True]

Die Zeitreihe der x-Komponente wird als normaler Plot definiert

ODETimeSeries[σ_,b_,r_,x0_,y0_,z0_,T_]:=Plot[Evaluate[{x[t]}/.ODEsol[σ,b,r,x0,y0,z0,T]],{t,0,T},PlotRange->All,Axes->False,Frame ->True]

Darstellung der   x - Komponente  zweier Zeitreihen mit unterschiedlichen Anfangsbedingungen

ODETimeSeries2[σ_,b_,r_,x0_,y0_,z0_,x20_,y20_,z20_,T_]:=Show[Plot[Evaluate[{x[t]}/.ODEsol[σ,b,r,x0,y0,z0,T]],{t,0,T},PlotRange->All,Axes->False,Frame ->True,PlotStyle->Red],Plot[Evaluate[{x[t]}/.ODEsol[σ,b,r,x20,y20,z20,T]],{t,0,T},PlotRange->All,Axes->False,Frame ->True]]

Experiment A: Aperiodisches Verhalen -> Lorenz-Attraktor

Darstellung der Zeitreihe der x-Komponente in Abhängigkeit von r

Manipulate[ODETimeSeries[σ,b,r,0,1,0,25],{r,0,40}]

Darstellung des Attraktors

Manipulate[ODETrajectory[σ,b,r,0,1,0,25],{r,0,40}]

Experiment B: Sensible Abhängigkeit von den Anfangsbedingungen

Darstellung der x-Komponente für zwei leicht gegeneinander verschobene Anfangsbedingungen in Abhängigkeit von r

Manipulate[ODETimeSeries2[σ,b,r,0,1,0,0,1.2,0,40],{r,0,40}]

Darstellung der x-Komponente für zwei leicht gegeneinander verschobene Anfangsbedingungen in Abhängigkeit von T mit r=26

Manipulate[ODETimeSeries2[σ,b,26,0,1,0,0,1.2,0,T],{T,5,40}]

Darstellung der x-Komponente für zwei leicht gegeneinander verschobene Anfangsbedingungen in Abhängigkeit von der Verschiebung d mit r = 26

Manipulate[ODETimeSeries2[σ,b,26,0,1,0,0,1+d,0,40],{d,0.01,0.2}]